iOS14.1 and iOS12.4.8 cannot find ESP32 BLE keyboard

[WebSamuraiDaisuke]

I use M5StickC have Code include BleKeyboard.h. But they cannot find the device as ESP32 BLE keyboard.
Win10 can find the device with Bluetooth.
How iOS find the device with BleKeyboard?

#include <M5StickC.h>
#include <BleKeyboard.h>

BleKeyboard bleKeyboard;

enum ConfSystem {
  mic = 0,
  video
} conf;
int n_conf = 2;
bool on_air;

void setup() {
  M5.begin();
  bleKeyboard.begin();

  Serial.println("Webconf Mute button");
  Serial.println("Push Button A (M5) to toggle MUTE");
  Serial.println("Push Button B to switch VideoOn or VideoOFF");
  M5.Lcd.setRotation(3); // BtnA is left side to LCD

  // default
  conf = mic;
  on_air = true;
  update_display();
}

void loop() {
  M5.update();
  
  if(M5.BtnA.wasPressed()){
    Serial.println("BtnA was pressed");
    if(bleKeyboard.isConnected()){
      on_air = !on_air;
      if(conf==mic){
        send_mute_mic();
      }
      else if(conf==video){
      send_off_video();
      }
    }
    else {
      Serial.println("BLE is not connected");
    }
    update_display();
  }

  if(M5.BtnB.wasPressed()){
    Serial.println("BtnB was pressed");
    conf = ConfSystem((conf+1) % n_conf);
    Serial.print("New ConfSystem: ");
    Serial.println(conf);
    update_display();
  }
  delay(10);
}

void update_display(){
  Serial.println("update_display");
  Serial.print("On air?: ");
  Serial.println(on_air);
  if(on_air){
    show_onair();
  }
  else {
    show_inmute();
  }
}

void show_onair(){
  M5.Lcd.fillScreen(TFT_RED);
  M5.Lcd.setTextColor(TFT_WHITE, TFT_RED);
  M5.Lcd.setTextSize(3);
  M5.Lcd.setTextDatum(MC_DATUM);
  M5.Lcd.drawString("ON AIR",80,40);

  M5.Lcd.setTextSize(2);
  M5.Lcd.setTextDatum(BR_DATUM);
  if(conf==mic){
    M5.Lcd.drawString("Mic",158,78);
  }
  else if (conf==video){
    M5.Lcd.drawString("Video", 158,78);  
  }
}

void show_inmute(){
  M5.Lcd.fillScreen(TFT_DARKGREY);
  M5.Lcd.setTextColor(TFT_WHITE, TFT_DARKGREY);
  M5.Lcd.setTextSize(3);
  M5.Lcd.setTextDatum(MC_DATUM);
  M5.Lcd.drawString("Muted...",80,40);

  M5.Lcd.setTextSize(2);
  M5.Lcd.setTextDatum(BR_DATUM);
  if(conf==mic){
    M5.Lcd.drawString("Mic",158,78);
  }
  else if (conf==video){
    M5.Lcd.drawString("Video", 158,78);  
  }
}

void send_mute_mic(){
  // https://support.zoom.us/hc/en-us/articles/205683899-Hot-Keys-and-Keyboard-Shortcuts-for-Zoom
  // Command(⌘)+Shift+A: Mute/unmute audio
  Serial.println("Toggle Mic");
  bleKeyboard.press(KEY_LEFT_GUI);
  bleKeyboard.press(KEY_LEFT_SHIFT);
  bleKeyboard.press('a');
  delay(100);
  bleKeyboard.releaseAll();
}

void send_off_video(){
  // https://www.cisco.com/c/en/us/td/docs/collaboration/CWMS/2_5/b_manage_meetings/b_manage_meetings_chapter_0100.html
  Serial.println("Toggle Video");
  bleKeyboard.press(KEY_LEFT_GUI);
  bleKeyboard.press(KEY_LEFT_SHIFT);
  bleKeyboard.press('v');
  delay(100);
  bleKeyboard.releaseAll();
}

[T-vK]

Which iOS version and which device and model are you using? Some are not compatible.

Edit: Sorry, I see the iOS version is mentioned in the title.

Take a look at #51

[WebSamuraiDaisuke]

2020年11月20日(金) 3:32 T-vK <[email protected]>:

Which iOS version and which device and model are you using? Some are not compatible.

iPhone 7 iOS 14.1 iPad 4 iOS 12.4.8 I knew you are the very genius programmer. I’d like you to make it to compatible for them. If you can make it I’d like you to give donation to you. Best regards Kai

--

Daisuke Kai Junkai Sent from iPhone

[WebSamuraiDaisuke]

2020年11月20日(金) 3:32 T-vK <[email protected]>:

Which iOS version and which device and model are you using? Some are not compatible

iPhone SE2 iOS 14.1 cannot find ESP32-BLE-Keyboard, too.

--

Daisuke Kai Junkai Sent from iPhone

[T-vK]

If you look at the list in #51 you can see that the iPhone 7 is not compatible.
And the iPhone SE 2nd Generation is compatible.

I don't know about the iPad 4. It may or may not work.

Please test it with the official example code that doesn't contain any M5 libraries.

[uolot]

Please test it with the official example code that doesn't contain any M5 libraries.

Just to add my 2c, I've been using this lib on M5Stack and M5Atom and using M5 libs, doesn't seem to affect BLE keyboard function at all. Thank you @T-vK for making and maintaining this great piece of software by the way! :)

[WebSamuraiDaisuke]

@uolot

Just to add my 2c,

What is your 2c?

[mbrunton22]

Yeah, I am also having issues on an iPhone 8 running 14.1 - just cannot see the advertisement (esp wroom 32)

[uolot]

@uolot

Just to add my 2c,

What is your 2c?

https://en.wikipedia.org/wiki/My_two_cents

[WebSamuraiDaisuke]

@T-vK, Will you make this library to be compatible with iOS and macOS in near future?

[T-vK]

It already is. Again, look at #51. Apple devices that don't properly support "Bluetooth Low Energy" will never work with this and there is nothing I can do about it.

[SunboX]

Same for me, but it worked with this code here some time ago (same Mac same iOS devices): https://gist.github.com/manuelbl/66f059effc8a7be148adb1f104666467

I have to re-test if this is still the case or if the Mac / iOS update also broke that snipped.

Tested devices:

MacBook Pro 2019
iPad 5. Generation
iPhone X

Tested with ESP32 DevKit v4

[mbrunton22]

Yeah, I am also having issues on an iPhone 8 running 14.1 - just cannot see the advertisement (esp wroom 32)

I actually got this working by making my device name really short (in my case I just set it to "Matt"), and it seemed to work after that on both my recent Ipad and an iphone 8 running IOS 14.

[WebSamuraiDaisuke]

Sorry for my late reply.
I had to make the device name shorter, every iOS can detect the device.